1.2.1. Wat is het aantal medewerkers (en het percentage t.o.v. totaal) met een zorgverlener functie per kwalificatieniveau per soort werkovereenkomst?

Concepten

• Arbeidsovereenkomst
• Arbeidsovereenkomst bepaalde tijd
• Arbeidsovereenkomst beroeps begeleidende leerweg
• Arbeidsovereenkomst onbepaalde tijd
• Inhuurovereenkomst
• ODB Kwalificatiewaarde
• Onverplaatsbaar artefact
• Oproepovereenkomst
• Stage-overeenkomst
• Uitzendovereenkomst
• Vestiging
• Vestigingsnummer
• Vrijwilligersovereenkomst
• Werkovereenkomst
• Werkovereenkomst afspraak
• Zorgverlener (functie)

Relaties

• deel van
• gaat over
• geïdentificeerd door
• heeft deel
• heeft eigenschap of kenmerk
• heeft eigenschapswaarde
• heeft opdrachtnemer

Eigenschappen

• einddatum
• heeft datawaarde
• startdatum

SPARQL query

Code gekopieerd
...
Kopieer naar klembord
1# Indicator: IGJ 1.2.1
2# Parameters: ?vestigingsnummer, ?peildatum
3# Ontologie: versie 3.0.0
4
5PREFIX onz-org: <http://purl.org/ozo/onz-org#>
6PREFIX onz-g: <http://purl.org/ozo/onz-g#>
7PREFIX onz-pers: <http://purl.org/ozo/onz-pers#>
8PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
9PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
10
11SELECT
12    ?kwalificatie_niveau
13    (SUM(?onbepaald) AS ?Aantal_medewerkers_met_een_werkovereenkomst_voor_onbepaalde_tijd_met_een_zorgverlener_functie) 
14    (SUM(?bepaald) AS ?Aantal_medewerkers_met_een_werkovereenkomst_voor_bepaalde_tijd_met_een_zorgverlener_functie)
15    (SUM(?oproep) AS ?Aantal_medewerkers_met_een_oproepovereenkomst_met_een_zorgverlener_functie)
16    (SUM(?bbl) AS ?Aantal_medewerkers_met_een_werkovereenkomst_BBL_met_een_zorgverlener_functie)
17    (SUM(?inhuur) AS ?Aantal_medewerkers_met_een_inhuurovereenkomst_met_een_zorgverlener_functie)
18    (SUM(?uitzend) AS ?Aantal_medewerkers_met_een_uitzendovereenkomst_met_een_zorgverlener_functie)
19    (SUM(?stage) AS ?Aantal_medewerkers_met_een_stageovereenkomst_met_een_zorgverlener_functie)
20    (SUM(?vrijwilliger) AS ?Aantal_medewerkers_met_een_vrijwilligersovereenkomst_met_een_zorgverlener_functie)
21    (SUM(?alle_soorten_ok) AS ?Totaal)
22{
23    SELECT DISTINCT
24		?type_overeenkomst
25		?persoon
26		?kwalificatie_niveau
27        ?onbepaald ?bepaald ?oproep ?bbl ?inhuur ?uitzend ?stage ?vrijwilliger
28        ?alle_soorten_ok
29    {
30        # BIND("2024-06-12"^^xsd:date AS ?peildatum)
31        BIND(?peildatum AS ?peildatum_argument)
32		?type_overeenkomst
33        	rdfs:subClassOf onz-pers:WerkOvereenkomst .
34    	FILTER(?type_overeenkomst != onz-pers:ArbeidsOvereenkomst && ?type_overeenkomst != onz-pers:WerkOvereenkomst)
35        ?overeenkomst 
36            a ?type_overeenkomst ;
37            onz-pers:heeftOpdrachtnemer ?persoon ;
38            onz-g:hasPart ?overeenkomst_afspraak .
39        ?overeenkomst_afspraak
40            a onz-pers:WerkOvereenkomstAfspraak ;
41            onz-g:startDatum ?start_afspraak .
42        OPTIONAL {
43            ?overeenkomst_afspraak onz-g:eindDatum ?eind_afspraak
44        }
45        FILTER(?start_afspraak <= ?peildatum_argument && (?eind_afspraak >= ?peildatum_argument || !BOUND(?eind_afspraak)))
46        #FILTER(?start_afspraak <= ?peildatum && (?eind_afspraak >= ?peildatum || !BOUND(?eind_afspraak)))
47        ?overeenkomst_afspraak onz-g:isAbout ?functie .                
48        ?functie 
49        	a onz-pers:ZorgverlenerFunctie ;
50     		onz-g:hasQuality /onz-g:hasQualityValue ?functie_niveau .
51    	{
52            ?functie_niveau
53                a onz-pers:ODBKwalificatieWaarde ;
54                rdfs:label ?kwalificatie_niveau .
55        } UNION {
56            BIND("Totaal aantal medewerkers" AS ?kwalificatie_niveau)
57        }
58        ?overeenkomst_afspraak onz-g:isAbout ?locatie .
59        ?locatie a onz-g:StationaryArtifact .
60        ?locatie onz-g:partOf* ?vestiging_uri .   
61        ?vestiging_uri
62        	a onz-org:Vestiging ;
63            onz-g:identifiedBy ?vestigingsnummer_object .
64        ?vestigingsnummer_object
65        	a onz-org:Vestigingsnummer ;
66        	onz-g:hasDataValue ?vestigingsnummer .
67    
68        BIND(IF (?type_overeenkomst = onz-pers:ArbeidsOvereenkomstOnbepaaldeTijd, 1, 0) AS ?onbepaald)
69        BIND(IF (?type_overeenkomst = onz-pers:ArbeidsOvereenkomstBepaaldeTijd, 1, 0) AS ?bepaald)
70        BIND(IF (?type_overeenkomst = onz-pers:OproepOvereenkomst, 1, 0) AS ?oproep)
71        BIND(IF (?type_overeenkomst = onz-pers:ArbeidsOvereenkomstBBL, 1, 0) AS ?bbl)
72        BIND(IF (?type_overeenkomst = onz-pers:InhuurOvereenkomst, 1, 0) AS ?inhuur)
73        BIND(IF (?type_overeenkomst = onz-pers:UitzendOvereenkomst, 1, 0) AS ?uitzend)
74        BIND(IF (?type_overeenkomst = onz-pers:StageOvereenkomst, 1, 0) AS ?stage)
75        BIND(IF (?type_overeenkomst = onz-pers:VrijwilligersOvereenkomst, 1, 0) AS ?vrijwilliger)
76        BIND(1 AS ?alle_soorten_ok)
77    } 
78}
79GROUP BY ?kwalificatie_niveau
80ORDER BY ?kwalificatie_niveau
81